#!/usr/bin/perl -w

# Quick script to draw an org chart from LDAP using the "manager" attribute

# Copyright (c) 2010 Bitcube Ltd.  Written by Adrian Bridgett

my $version = "1.0";

use strict;
use Getopt::Std;

sub usage() {
  print <<EOF;
  $0 [-h] [-l|-p]
    -h  This help
    -l  Landscape
    -p  Portrait (default)

EOF
  exit 0;
}

sub main()
{
  my %options=();
  my %person; # hash of uid -> (title, manager)
  
  getopts("hlp",\%options);
  
  usage() if defined ($options{h});
  
  parse_file(\%person);
  print_graph(\%person, defined($options{l}));
}

sub parse_file($) {
  my ($person) = (@_);
  my $dn;
  while (<>)
  {
    /^dn: uid=([^,]*)/ && do { $dn = $1 };
    /^manager: uid=([^,]*)/ && do { $$person{$dn}{manager} = $1 };
    /^(title|cn): (.*)/ && do { $$person{$dn}{$1} = $2 };
    /^memberOf: cn=(.*),o=Example/ && do { $$person{$dn}{group} = $1 };
  }
}

sub print_graph($$) {
  my ($person,$landscape) = @_;
  my ($rankdir,$lq,$rq) = $landscape ? ("BT","{","}") : ("RL","","");
  print <<EOF;
  digraph ldap {
    rankdir = $rankdir;
    node [shape=record];
EOF
  foreach (sort keys(%$person)) {
    my %d = %{$$person{$_}};
    if (! exists ($d{cn})) {
      $d{cn} = "anonymous";
      print STDERR "$_ has no Common Name\n";
    }
    $d{title}="" if ! exists ($d{title});
    $d{group}="" if ! exists ($d{group});
    print "\"$_\" [ label=\"$lq$d{cn}|$_|$d{title}|$d{group}$rq\" ]\n";
    if (exists($d{manager})) {
     print "  \"$_\" -> \"$d{manager}\";\n";
    }
  }
  print "}\n";
}


main;